IMAGE_REPOSITORY := "rancherlabs/eio-ghosts"
IMAGE_VERSION    := "0.3.1"

build-local:
  cargo build

build-image:
  docker build --tag {{ IMAGE_REPOSITORY }}:{{ IMAGE_VERSION }} .

publish-image: build-image
  docker push {{ IMAGE_REPOSITORY }}:{{ IMAGE_VERSION }}

run-local:
  cargo run

run-container: build-image
  docker run --rm -it --publish 8000:8000 {{ IMAGE_REPOSITORY }}:{{ IMAGE_VERSION }}

test-v1-encrypt:
  curl --fail --header "Content-Type: application/json" http://127.0.0.1:8000/v1/encrypt --data @test-payloads/v1/encrypt.json
  @echo

test-v1-push-repo owner="rancher-eio" repo="ghosts":
  curl --fail --header "Content-Type: application/json" http://127.0.0.1:8000/v1/push/{{ owner }}/{{ repo }}/testcase --data @test-payloads/v1/push/repo.json
  @echo

test-v1-push-org-all org="rancher-eio":
  curl --fail --header "Content-Type: application/json" http://127.0.0.1:8000/v1/push/{{ org }}/testcase_all --data @test-payloads/v1/push/org-all.json
  @echo

test-v1-push-org-none org="rancher-eio":
  curl --fail --header "Content-Type: application/json" http://127.0.0.1:8000/v1/push/{{ org }}/testcase_none --data @test-payloads/v1/push/org-none.json
  @echo

test-v1-push-org-selected org="rancher-eio":
  curl --fail --header "Content-Type: application/json" http://127.0.0.1:8000/v1/push/{{ org }}/testcase_selected --data @test-payloads/v1/push/org-selected.json
  @echo

test-live: test-v1-encrypt test-v1-push-org-all test-v1-push-org-none test-v1-push-org-selected test-v1-push-repo

deploy namespace="github-rancher-eio":
  kubectl apply --namespace={{ namespace }} --filename=manifest.yaml

undeploy namespace="github-rancher-eio":
  kubectl delete --namespace={{ namespace }} --filename=manifest.yaml