# 32K iNES ROM with optional 8K CHR

MEMORY
{
	ZP:     start =   $10, size =  $F0;
	RAM:    start =  $200, size =  $200;
	
	HEADER: start =     0, size =   $10, fill=yes;
	ROM:    start = $8000, size = $7E00, fill=yes, fillval=$FF;
	LOADER: start = $FE00, size =  $1F4, fill=yes, fillval=$FF;
	VECTORS:start = $FFF4, size =    $C, fill=yes;
	
	CHARS:  start =     0, size = $2000, fillval=$FF;
}

SEGMENTS
{
	ZEROPAGE:   load = ZP,      type = zp;
	NVRAM:      load = RAM,     type = bss, define=yes, optional=yes;
	BSS:        load = RAM,     type = bss;
	
	HEADER:     load = HEADER,  type = ro;
	DMC:        load = ROM,     type = ro, align=$100, optional=yes;
	CODE:       load = ROM,     type = ro, align=$100;
	RODATA:     load = ROM,     type = ro;
	CHARS_PRG:  load = ROM,     type = ro, align=$200, optional=yes;
	CHARS_PRG_ASCII:load = ROM, type = ro, align=$200, optional=yes;
	LOADER:     load = LOADER,  type = ro, optional=yes;
	VECTORS:    load = VECTORS, type = ro;
	
	CHARS:      load = CHARS,   type = ro, optional=yes;
	CHARS_ASCII:load = CHARS,   type = ro, align=$200, optional=yes;
}