# Maintainer: Jérémie Roquet <jroquet@arkanosis.net>
pkgname=smhkd
pkgver=0.2.0
pkgrel=0
pkgdesc="Simple MIDI hotkontrol daemon"
arch=("x86_64")
url="https://github.com/Arkanosis/smhkd"
license=("custom:ISC")
makedepends=("cargo" "git" "ruby-ronn")
checkdepends=("cargo")
source=("git+https://github.com/arkanosis/${pkgname}?signed") #tag=v0.2.0
md5sums=('SKIP')
validpgpkeys=("FA490B15D054C7E83F70B0408C145ABAC11FA702")

build() {
    cd "$srcdir/$pkgname"
    cargo build --release
    ronn < "$srcdir/$pkgname/docs/man/$pkgname.1.ronn" | gzip -9 > "$srcdir/$pkgname/docs/man/$pkgname.1.gz"
}

check() {
    cd "$srcdir/$pkgname"
    cargo test
}

package() {
    cd "$srcdir/$pkgname"
    install -Dm755 "target/release/$pkgname" "$pkgdir/usr/bin/$pkgname"
    install -Dm644 "docs/man/$pkgname.1.gz" "$pkgdir/usr/share/man/man1/$pkgname.1.gz"
    install -Dm644 "completion/bash/$pkgname" "$pkgdir/usr/share/bash-completion/completions/$pkgname"
    install -Dm644 "completion/zsh/_$pkgname" "$pkgdir/usr/share/zsh/site-functions/_$pkgname"
    install -Dm644 "README.md" "$pkgdir/usr/share/doc/$pkgname/README.md"
    install -Dm644 "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}