MEMORY
{
  /* NOTE 1 K = 1 KiBi = 1024 bytes */
  /* TODO Adjust these memory regions to match your device memory layout */
  /* MKL26Z64VFT4 */
  FLASH : ORIGIN = 0x00000000, LENGTH = 64K
  /* RAM is divided into 1/4 SRAM_L below 0x20000000 and 3/4 SRAM_U
  above 0x20000000, so there's 8k RAM starting at 0x20000000 - 2048 */
  RAM : ORIGIN = 0x1ffff800, LENGTH = 8K
}

/* This is where the call stack will be allocated. */
/* The stack is of the full descending type. */
/* You may want to use this variable to locate the call stack and static
   variables in different memory regions. Below is shown the default value */
/* _stack_start = ORIGIN(RAM) + LENGTH(RAM); */

/* You can use this symbol to customize the location of the .text section */
/* If omitted the .text section will be placed right after the .vector_table
   section */
/* This is required only on microcontrollers that store some configuration right
   after the vector table */
/* _stext = ORIGIN(FLASH) + 0x400; */

/* Example of putting non-initialized variables into custom RAM locations. */
/* This assumes you have defined a region RAM2 above, and in the Rust
   sources added the attribute `#[link_section = ".ram2bss"]` to the data
   you want to place there. */
/* Note that the section will not be zero-initialized by the runtime! */
/* SECTIONS {
     .ram2bss (NOLOAD) : ALIGN(4) {
       *(.ram2bss);
       . = ALIGN(4);
     } > RAM2
   } INSERT AFTER .bss;
*/

SECTIONS {
  .flashconfig ORIGIN(FLASH) + 0x400 : {
    LONG(0xFFFFFFFF);
    LONG(0xFFFFFFFF);
    LONG(0xFFFFFFFF);
    BYTE(0xDE);                 /* FSEC */
    BYTE(0xF9);                 /* FOPT */
    SHORT(0xFFFF);
  } > FLASH
  _stext = .;
}
INSERT BEFORE .text;